PowerPointのマクロで選択したオブジェクトの位置を設定する

PowerPointではVBAマクロを使えるが、記録機能がないため、全部自分で書かないといけない。

'=======================================
' オブジェクトの位置とサイズを設定する関数（エントリポイント）
'=======================================
Sub SetObjectSizePosition()

    ' ピクセルを cm に変換するための値
    Dim pt As Double
    pt = 28.3464567
    
    ' 設定
    ' 現状維持したい項目は Null に設定
    SetSelectedObjectSize 9.86 * pt, Null
    SetSelectedObjectPosition 9.86 * pt , 6.91 * pt
    
End Sub

'=======================================
' オブジェクトのサイズを設定する関数
'=======================================
Sub SetSelectedObjectSize(ByVal w As Variant, ByVal h As Variant)
    Dim shp As Shape

    If ActiveWindow.Selection.Type = ppSelectionShapes Then
        Set shp = ActiveWindow.Selection.ShapeRange(1)
        
        If IsNull(w) = False Then
            shp.Width = CDbl(w)
        End If
        
        If IsNull(h) = False Then
            shp.Height = CDbl(h)
            
        End If
    
    Else
        MsgBox "オブジェクトが選択されていません。"
    End If
    
End Sub

'=======================================
' オブジェクトの位置を設定する関数
'=======================================
Sub SetSelectedObjectPosition(ByVal x As Variant, ByVal y As Variant)
    Dim shp As Shape

    If ActiveWindow.Selection.Type = ppSelectionShapes Then
        Set shp = ActiveWindow.Selection.ShapeRange(1)
        
        If IsNull(x) = False Then
            shp.Left = CDbl(x)
        End If
                
        If IsNull(y) = False Then
            shp.Top = CDbl(y)
        End If
    Else
        MsgBox "オブジェクトが選択されていません。"
    End If
    
End Sub